Commit 13fd84b33c for freeswitch.com
commit 13fd84b33c302c508297bb387e1dcea1acb48e8d
Author: Andrey Volk <andywolk@gmail.com>
Date: Mon Jul 20 23:23:38 2026 +0300
[libyuv] Build AArch64 dotprod/i8mm/SVE/SME kernels with per-file -march to fix arm64/macOS build
diff --git a/Makefile.am b/Makefile.am
index 6d1982842d..ace180b046 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -180,7 +180,6 @@ libs/libyuv/source/compare.cc \
libs/libyuv/source/compare_common.cc \
libs/libyuv/source/compare_gcc.cc \
libs/libyuv/source/compare_hvx.cc \
-libs/libyuv/source/compare_neon64.cc \
libs/libyuv/source/compare_neon.cc \
libs/libyuv/source/compare_wasm.cc \
libs/libyuv/source/compare_win.cc \
@@ -203,11 +202,8 @@ libs/libyuv/source/rotate_gcc.cc \
libs/libyuv/source/rotate_hvx.cc \
libs/libyuv/source/rotate_lasx.cc \
libs/libyuv/source/rotate_lsx.cc \
-libs/libyuv/source/rotate_neon64.cc \
libs/libyuv/source/rotate_neon.cc \
libs/libyuv/source/rotate_rvv.cc \
-libs/libyuv/source/rotate_sme.cc \
-libs/libyuv/source/rotate_sve.cc \
libs/libyuv/source/rotate_wasm.cc \
libs/libyuv/source/rotate_win.cc \
libs/libyuv/source/row_any.cc \
@@ -216,11 +212,8 @@ libs/libyuv/source/row_gcc.cc \
libs/libyuv/source/row_hvx.cc \
libs/libyuv/source/row_lasx.cc \
libs/libyuv/source/row_lsx.cc \
-libs/libyuv/source/row_neon64.cc \
libs/libyuv/source/row_neon.cc \
libs/libyuv/source/row_rvv.cc \
-libs/libyuv/source/row_sme.cc \
-libs/libyuv/source/row_sve.cc \
libs/libyuv/source/row_wasm.cc \
libs/libyuv/source/row_win.cc \
libs/libyuv/source/scale_any.cc \
@@ -230,11 +223,9 @@ libs/libyuv/source/scale_common.cc \
libs/libyuv/source/scale_gcc.cc \
libs/libyuv/source/scale_hvx.cc \
libs/libyuv/source/scale_lsx.cc \
-libs/libyuv/source/scale_neon64.cc \
libs/libyuv/source/scale_neon.cc \
libs/libyuv/source/scale_rgb.cc \
libs/libyuv/source/scale_rvv.cc \
-libs/libyuv/source/scale_sme.cc \
libs/libyuv/source/scale_uv.cc \
libs/libyuv/source/scale_wasm.cc \
libs/libyuv/source/scale_win.cc \
@@ -242,6 +233,46 @@ libs/libyuv/source/video_common.cc
libfreeswitch_libyuv_la_CPPFLAGS = -O2 -fomit-frame-pointer -Ilibs/libyuv/include
+libfreeswitch_libyuv_la_LIBADD =
+
+# libyuv's AArch64 dot-product (udot), i8mm (usdot), SVE and SME kernels emit
+# instructions outside the baseline armv8-a target and are selected at runtime
+# by libyuv's own CPU detection. Build them as separate objects with the
+# required -march flags so the rest of the library stays portable to any
+# armv8-a CPU. This mirrors libs/libyuv/CMakeLists.txt.
+if LIBYUV_AARCH64
+noinst_LTLIBRARIES += libfreeswitch_libyuv_neon64.la
+libfreeswitch_libyuv_neon64_la_SOURCES = \
+libs/libyuv/source/compare_neon64.cc \
+libs/libyuv/source/rotate_neon64.cc \
+libs/libyuv/source/row_neon64.cc \
+libs/libyuv/source/scale_neon64.cc
+libfreeswitch_libyuv_neon64_la_CPPFLAGS = $(libfreeswitch_libyuv_la_CPPFLAGS)
+libfreeswitch_libyuv_neon64_la_CXXFLAGS = -march=armv8.2-a+dotprod+i8mm
+libfreeswitch_libyuv_la_LIBADD += libfreeswitch_libyuv_neon64.la
+
+noinst_LTLIBRARIES += libfreeswitch_libyuv_sve.la
+libfreeswitch_libyuv_sve_la_SOURCES = \
+libs/libyuv/source/rotate_sve.cc \
+libs/libyuv/source/row_sve.cc
+libfreeswitch_libyuv_sve_la_CPPFLAGS = $(libfreeswitch_libyuv_la_CPPFLAGS)
+libfreeswitch_libyuv_sve_la_CXXFLAGS = -march=armv8.5-a+i8mm+sve2
+libfreeswitch_libyuv_la_LIBADD += libfreeswitch_libyuv_sve.la
+
+if LIBYUV_AARCH64_SME
+noinst_LTLIBRARIES += libfreeswitch_libyuv_sme.la
+libfreeswitch_libyuv_sme_la_SOURCES = \
+libs/libyuv/source/rotate_sme.cc \
+libs/libyuv/source/row_sme.cc \
+libs/libyuv/source/scale_sme.cc
+libfreeswitch_libyuv_sme_la_CPPFLAGS = $(libfreeswitch_libyuv_la_CPPFLAGS)
+libfreeswitch_libyuv_sme_la_CXXFLAGS = -march=armv8.5-a+i8mm+sme
+libfreeswitch_libyuv_la_LIBADD += libfreeswitch_libyuv_sme.la
+else
+libfreeswitch_libyuv_la_CPPFLAGS += -DLIBYUV_DISABLE_SME
+endif
+endif
+
CORE_LIBS+=libfreeswitch_libyuv.la
endif
diff --git a/configure.ac b/configure.ac
index 9507ab6fe1..08be69e1ff 100644
--- a/configure.ac
+++ b/configure.ac
@@ -549,6 +549,28 @@ AC_ARG_ENABLE(libyuv,
AM_CONDITIONAL([ENABLE_LIBYUV],[test "${enable_libyuv}" = "yes"])
+# libyuv's AArch64 SIMD kernels (dot-product, i8mm, SVE, SME) use instructions
+# outside the baseline armv8-a target, so they must be compiled with per-file
+# -march flags (see Makefile.am). These conditionals mirror the logic in
+# libs/libyuv/CMakeLists.txt.
+AM_CONDITIONAL([LIBYUV_AARCH64],
+ [test "x$host_cpu" = "xaarch64" || test "x$host_cpu" = "xarm64"])
+
+libyuv_have_sme=no
+AS_IF([test "x$host_cpu" = "xaarch64" || test "x$host_cpu" = "xarm64"], [
+ AC_LANG_PUSH([C])
+ libyuv_save_CFLAGS="$CFLAGS"
+ CFLAGS="$CFLAGS -march=armv8.5-a+i8mm+sme"
+ AC_MSG_CHECKING([whether $CC supports AArch64 SME kernels])
+ AC_COMPILE_IFELSE([AC_LANG_SOURCE([[__arm_locally_streaming void func(void) { }
+int main(void) { return 0; }]])],
+ [libyuv_have_sme=yes])
+ AC_MSG_RESULT([$libyuv_have_sme])
+ CFLAGS="$libyuv_save_CFLAGS"
+ AC_LANG_POP([C])
+])
+AM_CONDITIONAL([LIBYUV_AARCH64_SME], [test "x$libyuv_have_sme" = "xyes"])
+
AC_ARG_ENABLE(libvpx,
[AC_HELP_STRING([--disable-libvpx],[build without libvpx])],[enable_libvpx="$enableval"],[enable_libvpx="yes"])